9: Einbindung eine
Excel-Tabelle zur Rudermomentberechnung
FLZcalc
ist auch dazu gedacht, daß die Anwender eigene Excel-Anwendungen einbinden und
aus FLZ-Vortex mit Daten versorgen. Anhand einer guten Anwendung zur Berechnung
von Rudermomenten, wird hier gezeigt, wie man das macht und sich für die
Zukunft Tipparbeit erspart.
Als
Beispiel soll Kräfte
an Rudern und Klappen von Bernhard Rögner dienen (siehe auch: RUDERMOMENTE
). Der Artikel dokumentiert ausführlich die theoretischen Hintergründe für das
zugehörige Excel RUDERMOMENTRECHNER.
Die hier gezeigt Einbindung wird nicht mit
ausgeliefert, weil das die Interessen des Autors verletzen könnte. Anhand
dieser Anleitung sollte aber ein mäßig geübter Excel- / OOcalc-Anwender in der
Lage sein, diese Anleitung für seine privaten Zwecke nachzuvollziehen.
Zuerst
laden wir 'RUDERMOMENTRECHNER.xls' von der angegebenen Internetseite und
speichern eine Kopie davon auf der Festplatte.
Den
Rudermomentrechner bauen wir in FLZcalc ein; dazu öffnen wir FLZcalc mit Excel
/ OOcalc und speichern es vorsichtshalber unter einem geänderten Namen ab, z.B.
'FLZcalc_0-8a.xls'. In dieser Datei arbeiten wir weiter und legen als erstes
eine neue Tabelle 'RM' an.
In
'RUDERMOMENTRECHNER.xls' wird die ganze Tabelle 'NÄHERUNGSFORMEL' markiert (auf
das rot markierte Feld oben links in der Tabelle klicken) und kopiert.
In
'FLZcalc_0-8a.xls / RM' wird die Kopie in Zelle 'A1' eingefügt. Die Datei
'RUDERMOMENTRECHNER.xls' kann jetzt geschlossen werden.
Mit
dieser Kopie verschwindet der störende Kennwortschutz, der es bisher nötig
machte bei Änderung eines Wertes in einem Eingabefeld das Kennwort 'CALC'
einzugeben. Also löschen wir den entsprechenden Hinweis in Tabelle 'RM'.
Excel
nimmt die Graphiken nicht mit, das Problem läßt sich aber leicht mit OOcalc
lösen. 'RUDERMOMENTRECHNER.xls' mit OOcalc öffnen, alles markieren, kopieren
und in eine neue leere OOcalc Tabelle einfügen. Jetzt lassen sich die Graphiken
einzeln kopieren und in die Excel-Datei übertragen.
Jetzt
werden die Eingabefelder an den Export von FLZ-Vortex angeschlossen. Für die
Berechnungen sind die Segmente 5 bis 9 heranzuziehen. Das kann man sich recht
einfach machen, nämlich wie im folgenden Bild gezeigt. Das hat aber den
Nachteil, daß man den Anschluß für jedes Flugzeug neu machen muß.
Die
elegantere Methode sieht so aus:
Wir
ermitteln das Segment in der die Wölbklappe zu finden ist mit einer Formel, der
sich nicht bei jedem Flugzeug ändert und greifen darüber auf die Daten zu.
Voraussetzung für diese Methode ist aber, daß man in FLZ-Vortex Wölbklappen in
der Gruppenbezeichnung immer „Wölbklappen“ nennt und die Querruder immer als
„Querruder“ bezeichnet. Diese Begriffe sind hier die Schlüssel.
Die
Formel für die Segmentnummer der Wölbklappen:
=SVERWEIS("Wölbklappen";INDIREKT("'AF1'!Q"
& 'AF1'!$K$1+Seg_root & ":V" &
'AF1'!$K$1+Seg_tip);SPALTE('AF1'!V:V)-SPALTE('AF1'!P:P);FALSCH)
Die
Funktion INDIREKT berechnet die Matrix für den SVERWEIS. Die Tabelle ist 'AF1',
die Spalten sind hardcodiert 'Q' und 'V', die Zeilen errechnen sich aus der
ersten Daten-Zeile des Segmentbereichs – Inhalt der Zelle AF1!$K$1 - plus
'Seg_root' (Zelle AF1!I1), sowie Inhalt der Zelle AF1!$K$1 plus 'Seg_tip'
(Zelle AF1!J1).
Die
Formel für die Segmentnummer der Querruder:
=SVERWEIS("Querruder";INDIREKT("'AF1'!Q"
& 'AF1'!$K$1+Seg_root & ":V" &
'AF1'!$K$1+Seg_tip);SPALTE('AF1'!V:V)-SPALTE('AF1'!P:P);FALSCH)
Und
so greift man auf die gesuchten Daten zu:
der
SVERWEIS liefert die prozentuale Klappentiefe!
Liste
der verwendeten Formeln
WK
Ruderklappentiefe innen
=E22/100
* SVERWEIS($G$3;INDIREKT("'AF1'!A" & 'AF1'!$K$1 &
":V" & 'AF1'!$L$1);SPALTE('AF1'!M:M);FALSCH)
WK
Ruderklappentiefe außen
=E23/100
* SVERWEIS($G$3;INDIREKT("'AF1'!A" & 'AF1'!$K$1 &
":V" & 'AF1'!$L$1);SPALTE('AF1'!N:N);FALSCH)
WK
Ruderklappenspannweite
=SVERWEIS($G$3;INDIREKT("'AF1'!A"
& 'AF1'!$K$1 & ":V" &
'AF1'!$L$1);SPALTE('AF1'!C:C);FALSCH)*1000
WK
Flügeltiefe an Ruderklappe innen
=SVERWEIS($G$3-1;INDIREKT("'AF1'!A"
& 'AF1'!$K$1 & ":V" &
'AF1'!$L$1);SPALTE('AF1'!D:D);FALSCH)*1000
WK
Flügeltiefe an Ruderklappe außen
=SVERWEIS($G$3;INDIREKT("'AF1'!A"
& 'AF1'!$K$1 & ":V" &
'AF1'!$L$1);SPALTE('AF1'!D:D);FALSCH)*1000
QR
Ruderklappentiefe innen
=F22/100
* SVERWEIS($G$4;INDIREKT("'AF1'!A" & 'AF1'!$K$1 &
":V" & 'AF1'!$L$1);SPALTE('AF1'!M:M);FALSCH)
QR
Ruderklappentiefe außen
=F23/100
* SVERWEIS($G$4;INDIREKT("'AF1'!A" & 'AF1'!$K$1 &
":V" & 'AF1'!$L$1);SPALTE('AF1'!N:N);FALSCH)
QR
Ruderklappenspannweite
=SVERWEIS($G$4;INDIREKT("'AF1'!A"
& 'AF1'!$K$1 & ":V" &
'AF1'!$L$1);SPALTE('AF1'!C:C);FALSCH)*1000
QR
Flügeltiefe an Ruderklappe innen
=SVERWEIS($G$4-1;INDIREKT("'AF1'!A"
& 'AF1'!$K$1 & ":V" &
'AF1'!$L$1);SPALTE('AF1'!D:D);FALSCH)*1000
QR
Flügeltiefe an Ruderklappe außen
=SVERWEIS($G$4;INDIREKT("'AF1'!A"
& 'AF1'!$K$1 & ":V" &
'AF1'!$L$1);SPALTE('AF1'!D:D);FALSCH)*1000
Fluggeschwindigkeit
=V_max
WK
& QR Ausschlagwinkel, Ruder- & Servohebellänge
manuelle
Erfassung
Die
Formeln für
Verhältnis mittlere
Ruderklappentiefe zu gemittelter Flügeltiefe
Ruderklappenmoment
(Scharniermoment)
Servomoment
Servodrehwinkel
erforderlich für ζ
bleiben
unverändert. Aus der Spalte 'E' werden sie in die Spalte 'F' für die Querruder
kopiert. Die Zellen 'E31' und 'F31' bekommen ein bedingtes Format:
Die
Zellen 'B32' und 'C32' werden verbunden....
...und
die ursprüngliche Formel =WENN((E28/E29)*SIN(E25*PI()/180)<1;"";"ACHTUNG:
ÄNDERE HEBELLÄNGE! - Ausschlaggröße nicht erreichbar!")
wird
ersetzt durch =WENN(ODER(E31="ACHTUNG!";F31="ACHTUNG!");"ACHTUNG:
Ändere Hebellänge! - Ausschlaggröße nicht erreichbar!";"")
und
die Zelle bekommt ein bedingtes Format.
Bereich
'Unter Berücksichtigung des Auftriebsbeiwerts'
Auftriebsbeiwert
=CA_max
Ruderklappenmoment
(Scharniermoment)
Formel bleibt
unverändert. Aus der Spalte 'E' wird er in die Spalte 'F' für die Querruder
kopiert.
Servomoment
die
originale Formel =E37*E39/E38
wird
ersetzt durch =E37*E29/E28
Servodrehwinkel
erforderlich für ζ
die
originale Formel =WENN((E38/E39)*SIN(E25*PI()/180)<1;ARCSIN((E38/E39)*SIN(E25*PI()/180))*57,3;"ACHTUNG!")
wird
ersetzt durch
=WENN((E28/E29)*SIN(E25*PI()/180)<1;ARCSIN((E28/E29)*SIN(E25*PI()/180))*57,3;"ACHTUNG!")
Die Formeln aus 'E40'
und 'E41' werden nach 'F40' und 'F41'; die Formate von 'E30' bis 'F31' werden
nach 'E40' bis 'F41' kopiert.
Die
Zellen 'B42' und 'C42' werden verbunden.... (siehe oben 'B32' und 'C32')
....und
die ursprüngliche Formel
=WENN((E38/E39)*SIN(E25*PI()/180)<1;"";"ACHTUNG:
ÄNDERE HEBELLÄNGE! - Ausschlaggröße nicht erreichbar!")
wird
ersetzt durch
=WENN(ODER(E41="ACHTUNG!";F41="ACHTUNG!");"ACHTUNG:
Ändere Hebellänge! - Ausschlaggröße nicht erreichbar!";"")
….und
die Zelle bekommt ein bedingtes Format.
Die
Zeilen für die Ruder- und Servohebellänge können jetzt gelöscht werden.
Und
jetzt sieht es so aus:
Von
diesem Stand ausgehend sind beliebige Erweiterungen möglich, eine soll hier
noch gezeigt werden. Folgende Zeilen werden eingefügt:
Auf
die Zellen 'E20' und 'F20' wird eine Gültigkeitsprüfung gelegt.
In die
neu eingefügten Zellen werden folgende Formeln eingetragen:
'E21': =SVERWEIS(E20;Servo!$A$3:$P$14;SPALTE(Servo!K:K);FALSCH)
'F21': =SVERWEIS(F20;Servo!$A$3:$P$14;SPALTE(Servo!K:K);FALSCH)
'E34': =E21/E33
'F34': =F21/F33
'E43': =E21/E42
'F43': =F21/F42
Auf
die Zellen 'E34', 'F34', 'E43' und 'F43' wird die gleiche bedingte Formatierung
gelegt.
Jetzt
können Servos aus einer Liste gewählt werden, die Drehmomente der gewählten
Servos werden angezeigt und es wird ein Sicherheitsfaktor berechnet, der aussagt,
ob die gewählten Servos geeignet sind.